Mencadangkan dan Memulihkan Pengaturan MicroSIP
Dengan dua file skrip .bat, Anda bisa mencadangkan pengaturan MicroSIP lalu memulihkannya kapan saja. Cara ini membantu agent yang pengaturan akun MicroSIP-nya sering hilang, sehingga tidak perlu mengatur ulang extension dari awal.
Sebelum memulai
- MicroSIP sudah terpasang di komputer Windows dan akun extension sudah berhasil online. Lihat Cara konfigurasi MicroSIP.
- Anda bisa membuka Notepad dan menyimpan file di komputer tersebut. Siapkan hak akses Administrator jika diperlukan.
Kedua skrip di bawah mencadangkan dan memulihkan dua lokasi pengaturan MicroSIP: registry Windows (HKEY_CURRENT_USER\Software\MicroSIP) dan file MicroSIP.ini di folder %AppData%\MicroSIP. Jika salah satu lokasi tidak ada di komputer Anda, skrip menampilkan pesan "not found" untuk lokasi itu.
Peringatan: File cadangan berisi data akun SIP, termasuk kredensial login extension. Jangan kirim lewat chat atau email, jangan simpan di folder bersama, dan hapus cadangan lama yang tidak dipakai.
Membuat skrip cadangan
- Buka Notepad.
- Salin kode berikut ke Notepad.
@echo off
REM Backup MicroSIP Registry and Configuration File
REM Define the backup folder
set backup_folder=%~dp0MicrosipBackup
mkdir "%backup_folder%"
REM Backup Registry settings
reg export "HKEY_CURRENT_USER\Software\MicroSIP" "%backup_folder%\MicrosipRegistryBackup.reg" /y
REM Backup Configuration file
set config_file=%AppData%\MicroSIP\MicroSIP.ini
if exist "%config_file%" (
copy "%config_file%" "%backup_folder%\MicroSIP.ini"
) else (
echo Configuration file not found!
)
echo Backup completed. Files saved in: "%backup_folder%"
pause
- Pilih File > Save As.
- Ubah Save as type menjadi All Files. Di Windows berbahasa Indonesia, nama menu ini bisa sedikit berbeda.
- Beri nama file backup_microsip.bat, lalu klik Save.
Membuat skrip pemulihan
- Buka Notepad baru.
- Salin kode berikut ke Notepad.
@echo off
REM Restore MicroSIP Registry and Configuration File
REM Define the backup folder
set backup_folder=%~dp0MicrosipBackup
REM Restore Registry settings
if exist "%backup_folder%\MicrosipRegistryBackup.reg" (
reg import "%backup_folder%\MicrosipRegistryBackup.reg"
) else (
echo Registry backup file not found!
)
REM Restore Configuration file
if exist "%backup_folder%\MicroSIP.ini" (
copy "%backup_folder%\MicroSIP.ini" "%AppData%\MicroSIP\MicroSIP.ini" /y
) else (
echo Configuration file backup not found!
)
echo Restore completed.
pause
start %localappdata%\MicroSIP\microsip.exe
- Pilih File > Save As, ubah Save as type menjadi All Files.
- Beri nama restore_microsip.bat dan simpan di folder yang sama dengan backup_microsip.bat.
Menjalankan skrip
- Pastikan pengaturan MicroSIP sudah benar dan extension online.
- Klik dua kali backup_microsip.bat. Tekan tombol apa saja saat jendela meminta untuk menutup.
- Saat pengaturan MicroSIP hilang, klik dua kali restore_microsip.bat.
Hasil: Skrip cadangan membuat folder MicrosipBackup di samping file .bat, berisi MicrosipRegistryBackup.reg dan MicroSIP.ini. Skrip pemulihan menyalin keduanya kembali ke lokasi asal, lalu mencoba membuka MicroSIP.
Catatan: Baris terakhir skrip pemulihan membuka MicroSIP dari folder %localappdata%MicroSIP. Jika MicroSIP di komputer Anda terpasang di folder lain, MicroSIP tidak terbuka otomatis. Buka MicroSIP secara manual setelah skrip selesai.
Tips: Buat shortcut restore_microsip.bat di desktop dan minta agent membuka MicroSIP lewat shortcut itu. Pengaturan dipulihkan setiap kali shortcut itu dijalankan.
Troubleshooting
Muncul pesan "not found": file cadangan belum ada. Jalankan backup_microsip.bat terlebih dulu, dan pastikan kedua file .bat ada di folder yang sama.
Skrip gagal mengubah pengaturan: klik kanan file .bat, lalu pilih Run as administrator.
Masih bermasalah?
Hubungi tim support melalui live chat di pojok kanan bawah support.barantum.com atau email support@barantum.com. Sertakan pesan yang muncul di jendela skrip.